;+
; NAME:
;   ml_setwcalib
;
; PURPOSE:
;   Returns the default MaNGA master wavelength vector in a 
;   double-precision array.  Returned values are given in Angstroms.
;
;   Default is to return the MaNGA logarithmically sampled wavelength
;   array, which runs from log10(wave/Angstroms)=3.5589 to 4.0151 with a step
;   size of delta(log10(wave/Angstroms))=1e-4
;
;   If called with the /linear keyword set it will instead return the
;   MaNGA linearly sampled wavelength array, which runs from 3622.0 
;   to 10353.0 Ang with a step size of 1 Angstrom.
;
; CALLING SEQUENCE:
;   wave=ml_setwcalib([/visual])
;
; INPUTS:
;
; OPTIONAL INPUTS:
;
; OPTIONAL KEYWORDS:
;   linear  -  Returns the linearly sampled wave solution instead of
;             log sampled
;   doublesamp - Doubles the sampling of the wave solution
;
; OUTPUT:
;
; COMMENTS:

; EXAMPLES:
;
; BUGS:
;
; PROCEDURES CALLED:
;
; INTERNAL SUPPORT ROUTINES:
;
; REVISION HISTORY:
;   October-2013  Written by David Law (Dunlap Institute; drlaw@di.utoronto.ca)
;   21-Apr-2014  Removed blue wavelengths that are too poor performance (D. Law)
;   02-Jul-2018  Add option to double the sampling (D. Law)
;-
;------------------------------------------------------------------------------

function ml_setwcalib,linear=linear,doublesamp=doublesamp

if (keyword_set(linear)) then begin
  lam0=3622.0D
  lam1=10353.0D
  dlam=1.0D
  if (keyword_set(doublesamp)) then dlam=dlam/2.
  nlam=long((lam1-lam0)/dlam+1)
  wave=dindgen(nlam)*dlam+lam0
endif else begin
  lam0=3.5589D
  lam1=4.0151D
  dlam=1d-4
  if (keyword_set(doublesamp)) then dlam=dlam/2.
  nlam=long((lam1-lam0)/dlam+1)
  logwave=dindgen(nlam)*dlam+lam0
  wave=10.D^logwave
endelse

return,wave
end